DouKaku?beta

challenge ポーカーの役判定

引数に手札を与えると、ポーカーの役を表示するプログラムを作ってください。

条件：

  • スートはS,D,H,C、ランクはA,2～9,T,J,Q,Kのそれぞれ一文字で表します。
  • 手札は S2D5H3CQS9 のように10文字で指定されます。特にソートはされていません。
  • 手札にジョーカーは含まれません。
  • ストレートで取りうるランクの種類はA2345, 23456 ... 9TJQK, TJQKAの10種類で、JQKA2のようにK-A-2をまたぐものはストレートではありません。

実行例：

% ./poker SQSJSASKST
Royal flush

% ./poker D9D7D6D5D8
Straight flush

% ./poker C2D2S2H3H2
Four of a kind

% ./poker C2D3S2H3H2
Full house

% ./poker S9S4S8STSJ
Flush

% ./poker C4H7D5S6H3
Straight

% ./poker S6H6C5DQC6
Three of a kind

% ./poker S6HQC5DQC6
Two pair

% ./poker S6H4C5DQC6
One pair

% ./poker SJSQSKSAC2
No pair

see: ポーカー - Wikipedia

お題にしようと思っていたのに間違えてしまいました。今から変更可能でしょうか？

(説明)
当初間違ってトピックに投稿していたので、このようなコメントを付けていたのですが、
このコメントに気づいた管理人さんにお題に移していただきました。
(最初の2つだけ投稿日時が早いのはそのためです)
post comment

Posted feedbacks - Scheme

Schemeがないので, 適当なパターンマッチで書いたものを投稿します

エラー判定はしていないので "ASASASASAS"等も受け入れます

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
(use srfi-1)
(use util.match)

(define (poker hand)
  (define (rank->num a)
    (cond [(char-set-contains? #[\d] a) (digit->integer a)]
          [(char=? #\A a) 14]
          [(char=? #\T a) 10]
          [(char=? #\J a) 11]
          [(char=? #\Q a) 12]
          [(char=? #\K a) 13]
          [else a]))
  (define (decision nums suits)
    (let1 flags (map - (cdr nums) nums) ;;次のカードとの差
          (cond ((fold (lambda (a r) (and (eq? a (car suits)) r)) #t suits) ;; FLUSH
                 (match flags
                        ((1 1 1 1) (if (= 10 (car nums)) "Royal flush" "Straight flush"))
                        ((1 1 1 9) "Straight flush") ;; 2 3 4 5 14用
                        (else "Flush")))
                (else
                 (match flags
                        ((0 0 0 _) "Four of a kind")
                        ((_ 0 0 0) "Four of a kind")
                        ((0 0 _ 0) "Full house")
                        ((0 _ 0 0) "Full house")
                        ((1 1 1 1) "Straight")
                        ((1 1 1 9) "Straight") ;; 2 3 4 5 14用
                        ((_ _ 0 0) "Three of a kind")
                        ((_ 0 0 _) "Three of a kind")
                        ((0 0 _ _) "Three of a kind")
                        (else
                         (match (sort flags <)
                                ((0 0 _ _) "Two pair")
                                ((0 _ _ _) "One pair")
                                (else "No pair"))))))))
  (receive (nums suits)
           (partition number? (map rank->num (string->list hand)))
           (decision (sort nums <) suits)))

(map poker
     '("SQSJSASKST" "D9D7D6D5D8" "C2D2S2H3H2" "C2D3S2H3H2" "S9S4S8STSJ"
       "C4H7D5S6H3" "S6H6C5DQC6" "S6HQC5DQC6" "S6H4C5DQC6" "SJSQSKSAC2"))
;=>
;("Royal flush" "Straight flush" "Four of a kind" "Full house" "Flush"
; "Straight" "Three of a kind" "Two pair" "One pair" "No pair")

Index

Feed

Other

Link

Pathtraq

loading...
Creative Commons License このサイトの内容は、 クリエイティブ・コモンズ・ライセンスの下でライセンスされています。 [詳細]