コメントの削除 in Brainf*ck DouKaku?

コメントの削除

ソースコードからコメント部分を削除するプログラム decomment を書いてください．
すくなくとも，decomment を記述したのと同じ言語で書かれているソースコードが
扱えるようにしてください．

post comment

Posted feedbacks - Brainf*ck

Brainf*ckで。入力された文字のうち、コメント（実行可能な８文字以外全部）を削除します。終了せず、ひたすら入力を待ち続けるので適当に止めてください。

Brainfuck Developerで実行する場合は複数行の入力ができませんが、[Extras] - [Set Input File ...] から入力ファイルを指定できます。すばらしいツールです。あとは言語が良けりゃぁ言うことなし。

+[>
  ,                      # {1} = input char
  >+<                    # {2} = 1
  [->>+>+<<<]            # {3:4} = !{1}
  >>>
  >++++++[-<------->]<-  # {4} = {4} minus 43
  [                      # if {4} not 43 (plus)
    -[                   # if {4} not 44 (comma)
      -[                 # if {4} not 45 (minus)
        -[               # if {4} not 46 (dot)
          >++++[-<---->]<++
          [              # if {4} not 60 (lt)
            --[          # if {4} not 62 (gt)
              >+++++[-<------>]<+
              [          # if {4} not 91 (open)
                --[      # if {4} not 93 (close)
                  <<->>  #   then {2} = 0
                  [-]
                ]
              ]
            ]
          ]
        ]
      ]
    ]
  ]
  <<
  [>.<-]                 # if {2} then print {3}
  >[-]<<
<]

DouKaku?

コメントの削除

Posted feedbacks - Brainf*ck

Index

Feed

Other

Link

Pathtraq