DouKaku?

module win32.clipboard;
private import std.c.windows.windows;
private import std.contracts, std.conv;

export extern(Windows) {
    HGLOBAL GlobalAlloc(UINT uFlags, DWORD dwBytes);
    HGLOBAL GlobalFree(HGLOBAL hMem);
    LPVOID GlobalLock(HGLOBAL hMem);
    BOOL GlobalUnlock(HGLOBAL hMem);
    enum UINT GMEM_MOVEABLE = 2;
    
    BOOL CloseClipboard();
    BOOL EmptyClipboard();
    UINT EnumClipboardFormats(UINT format);
    HANDLE GetClipboardData(UINT uFormat);
    BOOL OpenClipboard(HWND hWndNewOwner);
    HANDLE SetClipboardData(UINT uFormat, HANDLE hMem);
    
    enum UINT CF_UNICODETEXT = 13;
}

public static class Clipboard {    
    static void setText(string text) {
        enforce(OpenClipboard(null));
        scope(exit) CloseClipboard();
        
        auto wtext = to!(wstring)(text);
        auto data = enforce(GlobalAlloc(GMEM_MOVEABLE, wchar.sizeof * (wtext.length + 1)));
        scope(failure) GlobalFree(data);
        
        {
            auto pdata = cast(wchar*)GlobalLock(data);
            scope(exit) GlobalUnlock(data);
            
            pdata[0..wtext.length] = wtext;
            pdata[wtext.length] = '\0';
        }
        
        enforce(EmptyClipboard());
        enforce(SetClipboardData(CF_UNICODETEXT, data));
    }
    
    static string getText() {
        enforce(OpenClipboard(null));
        scope(exit) CloseClipboard();
        
        auto data = GetClipboardData(CF_UNICODETEXT);
        if(!data) return null;
        
        auto pdata = cast(const(wchar)*)GlobalLock(data);
        auto wtext = pdata[0..strlen(pdata)];
        GlobalUnlock(data);
        
        return to!(string)(wtext);
    }
}

private uint strlen(const(wchar)* s) {
    uint len;
    while(*s++) len++;
    return len;
}

debug(Clipboard) {
import std.stdio;

void main() {
    Clipboard.setText("test テスト");
    writeln(Clipboard.getText);
}

}