2次元ランダムウォーク
Posted feedbacks - Perl
2次元ランダムウォークを描け というお題だと解釈しました。 というわけで、Image::Magickで描いてみました。
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 | use strict;
use warnings;
use List::Util qw/min max/;
use Image::Magick;
# 歩く回数
my $count = 10000;
sub _walk { int(rand(3))-1; }
# 歩いて範囲を測定
my @current = (0,0);
my @area = (@current, @current);
my @footmarks;
for my $fm (map { [_walk, _walk] } 1 .. $count) {
$current[0] += $fm->[0];
$current[1] += $fm->[1];
$area[0] = min $area[0], $current[0];
$area[1] = min $area[1], $current[1];
$area[2] = max $area[2], $current[0];
$area[3] = max $area[3], $current[1];
push @footmarks, [@current];
}
# 軌跡を書く
my $grid = 8;
my $lsize = 2;
my $img = Image::Magick->new;
$img->Set(
size=>join(q/x/, map { ($_+1) * $grid } $area[2]-$area[0], $area[3]-$area[1])
);
$img->Read(q/xc:white/);
$img->Draw(primitive => q/polyline/, stroke => q/black/, strokewidth => $lsize,
points => join(q/ /, map { join q/,/, map { $_ * $grid + $grid/2 } @$_ }
map { [$_->[0]-$area[0],$_->[1]-$area[1]] }
@footmarks)
);
# start地点にバッテン
$img->Draw(primitive => q/line/, stroke => q/red/, strokewidth => $lsize/2,
points => join(q/ /, map { join q/,/, map { $_ * $grid } @$_ }
map { [$_-$area[0], $_-$area[1]] }
0, 1)
);
$img->Draw(primitive => q/line/, stroke => q/red/, strokewidth => $lsize/2,
points => join(q/ /, map { join q/,/, map { $_ * $grid } @$_ }
map { [$_->[0]-$area[0], $_->[1]-$area[1]] }
[1,0], [0,1])
);
$img->Write(q/rwalk.png/);
|
ytakenaka
#6806()
Rating2/2=1.00
２次元ランダムウォークをつくってみてください。
＊＊＊＊＊＊
元は3本建てにしようかと思ったけど、上の一本に絞りました。おまけとして、3本とも下に補足しておきます。作れるようでしたら作ってみてください。
1.一次元のランダムウォークを作ってください。
1.1 データファイルに残してください。 フォーマット：時間 位置
おまけ）
可視化が簡単な処理系・プログラミング言語でしたら実際に可視化してみてください。フォーマットしたファイルをスプレッドシートやplotutilitiesなどの可視化ソフトを使って、実際に動きをかくにんしてみましょう。:-)
2.同じように2次元のランダムウォークを作ってください。
2.1 1.1と同じようにしてください。
フォーマット：時間 x位置 y位置
3.凝りたければ、アニメーションにするもよし、3次元の動きをとるもよし、自分の想像力がいかせるところまでやってみてください。
http://ja.wikipedia.org/wiki/%E3%83%A9%E3%83%B3%E3%83%80%E3%83%A0%E3%82%A6%E3%82%A9%E3%83%BC%E3%82%AF
分からないというヒトへの分かりにくいヒント：
今の位置から次の時間の位置が決まるのですが、決まりかたが、乱数で一歩後退するか一歩先にいくか?ということをやればよいです。
[ reply ]