DouKaku?

＜入力例＞
ドウカク org ヘ ヨウコソ
コノ サイト ハ ダサレタ オダイ ヲ イカニ トクカ キソイアウ
 プログラマ ノ タメノ コロシアム デス
トウコウ ヲ タメシテ ミタイ カタ ハ テスト
トリアエズ ナガメテ ミタイ カタ ハ ゲンゴ ノ イチラン ガ オススメ デス

＜出力例＞
ドウモク org ヘ ヨウコソ
コノ ザレゴト ハ ダサレタ オダイ ヲ イワハダ トシシタ キソイアウ
 プログラマ ノ タチノミ コロシアム デス
トウコウ ヲ ハナシテ ミチノリ カタ ハ プリント
トリアエズ ナガメテ ミツリン カタ ハ ゲンゴ ノ キンラン ガ オススメ デス

#!/usr/bin/env groovy
final MIN_SIMILARITY_RATE = 0.51

def wordList = []
["fam25_10.txt", "fam40_25.txt", "fam55_40.txt", "fam70_55.txt"].each{
    Collections.addAll(wordList, new File(it).text.split(/\s/))
}
def file = new File("inputSample.txt")
assert wordList
assert file?.exists()

println file.text.replaceAll(/(?m)\S+/){ word ->
    def convertList = [ word, *wordList.findAll{ other ->
        getSimilarityRate(word, other) >= MIN_SIMILARITY_RATE
    } ]
    Collections.shuffle(convertList)
    convertList[0]
}

double getSimilarityRate(String str1, String str2){
    def len1 = str1.size()
    def len2 = str2.size()

    def matrix = new int[len1+1][len2+1]
    
    for(int i = 0; i < matrix.size(); i++){
        matrix[i][0] = i
    }
    for(int i = 0; i < matrix[0].size(); i++){
        matrix[0][i] = i
    }
    
    for(int i = 0; i < len1; i++){
        for(int j = 0; j < len2; j++){
            int cost = (str1[i] == str2[j]) ? 0 : 1
            matrix[i+1][j+1] = [matrix[i][j+1] +1, matrix[i+1][j] +1, matrix[i][j] +cost].min()
        }
    }
    
    def longer = [len1, len2].max()
    (longer - matrix[len1][len2])/longer
}