DouKaku?

#!/usr/local/bin/perl
use strict;
use warnings;
use utf8;

my %direction = (
  上 => [0, -1], 右上 => [ 1, -1], 右 => [ 1, 0], 右下 => [ 1,  1],
  下 => [0,  1], 左下 => [-1,  1], 左 => [-1, 0], 左上 => [-1, -1]
);

sub search8 {
    my @word = split //, shift;
    my @field = map { chomp; [ split //, $_ ] } split /[\r\n]+/, shift;
    my @result;
    for my $y ( 0 .. @field - 1 ) {
        for my $x ( 0 .. @{ $field[$y] } - 1 ) {

            # warn join(",", $x, $y, $field[$y][$x]);
          LOOP: for my $d ( sort keys %direction ) {
                my $lx = $x;
                my $ly = $y;
                for my $c (@word) {
                    next LOOP if $lx < 0 || $lx >= @{ $field[$y] };
                    next LOOP if $ly < 0 || $ly >= @field;
                    next LOOP if $field[$ly][$lx] ne $c;
                    $lx += $direction{$d}->[0];
                    $ly += $direction{$d}->[1];
                }
                push @result, "($x, $y), $d";
            }
        }
    }
    @result;
}

$\ = "\n";
binmode STDOUT => ':utf8';
print join "\n", search8( 'ウオリ', <<"EOT");
リオウウリウ
ウオリウオリ
オリリオリウ
リリオオウオ
EOT

__END__