DouKaku?

package modulo;
use strict;
use warnings;
our $VERSION = 0.01;

use overload
  '0+' => sub { $_[0]->[0] + 0 },
  '+'  => sub { __PACKAGE__->new( $_[0]->[0] + $_[1]->[0], $_[0]->[1] ) },
  '-'  => sub { __PACKAGE__->new( $_[0]->[0] - $_[1]->[0], $_[0]->[1] ) },
  '*'  => sub { __PACKAGE__->new( $_[0]->[0] * $_[1]->[0], $_[0]->[1] ) },
  ;

sub import {
    my ( $pkg, undef, $mod ) = @_;
    $mod >= 2 or die 'usage: use ', __PACKAGE__, ' mod => n;';
    overload::constant integer => sub { __PACKAGE__->new( shift, $mod ) };
}

sub new {
    my $pkg = shift;
    my ( $n, $m ) = @_;
    $n %= $m;
    bless [ $n, $m ], $pkg;
}

1;

#!/usr/local/bin/perl
use strict;
use warnings;
sub say { print @_, "\n" }
say "1 + 2 = ", 1 + 2;
say "3 - 4 = ", 3 - 4;
say "5 * 6 = ", 5 * 6;
{
    say "# mod = 2";
    use modulo mod => 2;
    say "1 + 2 = ", 1 + 2;
    say "3 - 4 = ", 3 - 4;
    say "5 * 6 = ", 5 * 6;
}
{
    say "# mod = 3";
    use modulo mod => 3;
    say "1 + 2 = ", 1 + 2;
    say "3 - 4 = ", 3 - 4;
    say "5 * 6 = ", 5 * 6;
}

say "# original scope";
say "1 + 2 = ", 1 + 2;
say "3 - 4 = ", 3 - 4;
say "5 * 6 = ", 5 * 6;