DouKaku?

import std.string, std.conv, std.contracts,
       std.random, std.stdio, std.c.time;

class Field {
    private uint width_, height_;
    private bool[] data_;
    
    this(uint width, uint height) {
        this.width_ = width;
        this.height_ = height;
        this.data_ = new bool[width * height];
    }
    
    const uint width() { return this.width_; }
    const uint height() { return this.height_; }
    
    const bool opIndex(uint x, uint y)
        in {
            assert(x < this.width);
            assert(y < this.height);
        }
        body {
            return this.data_[this.width * y + x];
        }
        
    bool opIndexAssign(bool value, uint x, uint y)
        in {
            assert(x < this.width);
            assert(y < this.height);
        }
        body {
            return this.data_[this.width * y + x] = value;
        }
    
    const string toString() {
        const len = (3 * this.width) * this.height + newline.length * (this.height - 1);
        auto s = new char[len], idx = 0;
        foreach(y; 0 .. this.height) {
            foreach(x; 0 .. this.width) {
                s[idx .. idx + 3] = this[x, y] ? "[*]" : "[ ]";
                idx += 3;
            }
            if(idx != len) {
                s[idx .. idx + newline.length] = newline;
                idx += newline.length;
            }
        }
        return assumeUnique(s);
    }
    
    const Field nextGeneration() {
        const w = this.width, h = this.height;
        Field f = new Field(w, h);
        foreach(y; 0 .. h) {
            foreach(x; 0 .. w) {
                int c;
                int l = (x + w - 1) % w, r = (x + 1) % w,
                    u = (y + h - 1) % h, d = (y + 1) % h;
               
                if(this[l, u]) c++; if(this[x, u]) c++; if(this[r, u]) c++;
                if(this[l, y]) c++;                     if(this[r, y]) c++;
                if(this[l, d]) c++; if(this[x, d]) c++; if(this[r, d]) c++;
                
                if(c == 3 || this[x, y] && c == 2)
                    f[x, y] = true;
            }
        }
        return f;
    }
}

void main(string[] args) {
    if(args.length < 3) return;
    auto width = to!(uint)(args[1]), height = to!(uint)(args[2]);
    
    auto f = new Field(width, height);
    auto rgen = Random(unpredictableSeed);
    foreach(y; 0 .. height) {
        foreach(x; 0 .. width) {
            f[x, y] = uniform!(int)(rgen, 0, 10) < 3;
        }
    }
    uint gen = 0;
    while(true) {
        writeln("Generation ", ++gen);
        writeln(f);
        writeln("");
        f = f.nextGeneration;
        msleep(100);
    }
}