DouKaku?

private import std.stdio, std.string, std.algorithm, std.random, std.contracts;

const target = "METHINKSITISAWEASEL";
const capacity = 300;
const children = 5;

Random rand;
static this() {
    rand = Random(unpredictableSeed);
}

void main() {
    auto strings = new string[capacity];
    foreach(ref s; strings) s = randomString;

    int generation;
    do {
        auto temp = new string[strings.length * children];
        foreach(i, ref s; temp) s = changeChar(strings[i/children]);
        schwartzSort!(distance)(temp);
        strings = temp[0..capacity];

        writefln("[%s] %s (%s)", ++generation, strings[0], distance(strings[0]));
    } while(strings[0] != target);
    writefln("Now, we have %s!", target);
}

char randomChar() {
    alias UniformDistribution!(int, "[]") Dist;

    return Dist('A', 'Z').next(rand);
}

string randomString() {
    auto result = new char[target.length];
    foreach(ref c; result) c = randomChar;
    return assumeUnique(result);
}

string changeChar(string str) {
    alias UniformDistribution!(int) Dist;

    auto result = str.dup;
    result[Dist(0, result.length).next(rand)] = randomChar;
    return assumeUnique(result);
}

int distance(string str) {
    int d;
    assert(str.length == target.length);
    foreach(i; 0..target.length) {
        if(str[i] != target[i]) ++d;
    }
    return d;
}