DouKaku?

implement Comment;

include "sys.m";
    sys: Sys;
    print, fprint, sprint, create, OWRITE: import sys;
include "draw.m";
include "bufio.m";
include "xml.m";
    xml: Xml;
    Parser, Item, Locator, Attributes, Mark: import xml;

Comment: module
{
    init: fn(ctxt: ref Draw->Context, argv: list of string);
};

init(nil: ref Draw->Context, nil: list of string)
{
    sys = load Sys Sys->PATH;
    xml = load Xml Xml->PATH;
    xml->init();

    data := "<?xml ..";
    fout := create("/tmp/comment.xml", OWRITE, 8r600);
    if(fout == nil)
        raise "open";
    fprint(fout, "%s", data);
    fout = nil;
    printlastbuilddate("/tmp/comment.xml");
}

printlastbuilddate(f: string)
{
    warningch := chan of (Xml->Locator, string);
    spawn warningproc(warningch);

    (x, e) := xml->open(f, warningch, "");
    if(x == nil)
        raise e;
    for(xi := x.next(); xi != nil; xi = x.next())
        pick i := xi {
        Tag =>
            case i.name {
            "rss" or "channel" =>
                x.down();
            "lastBuildDate" =>
                x.down();
                print("%s\n", gettext(x));
                warningch <- = (x.loc, nil);        # term
                exit;
            }
        Error =>
            raise i.msg;
        }
    warningch <- = (x.loc, nil);
    raise "no item";
}

gettext(x: ref Parser): string
{
    for(xi := x.next(); xi != nil; xi = x.next())
        pick i := xi {
        Text =>
            return i.ch;
        }
    raise "error";
}

warningproc(c: chan of (Xml->Locator, string))
{
    for(;;){
        (loc, msg) := <- c;
        if(msg == nil)
            break;
        print("%s:%d: %s", loc.systemid, loc.line, msg);
    }
}