DouKaku?

RosslerLine[] lines;
float zoom, rotX, rotY;
void setup() {
  lines = new RosslerLine[3];
  lines[0] = new RosslerLine(0.2, 0.1, 5.7, 1, 1, 1, 0x33FF0000);
  lines[1] = new RosslerLine(0.2, 0.2, 5.7, 1, 1, 1, 0x3300FF00);
  lines[2] = new RosslerLine(0.2, 0.3, 5.7, 1, 1, 1, 0x330000FF);
  size(500, 500, P3D);
  zoom = 7.8;
  rotX = 1.0;
  rotY = -0.8;
  clearScreen();
}
void preDraw() {
  pushMatrix();
  translate(width / 2, height / 2);
  rotateX(rotX);
  rotateY(rotY);
  scale(zoom);
}  
void postDraw() {
  popMatrix();
}
void clearScreen() {
  preDraw();
  background(0);
  stroke(64);  line(0, 0, 0, 30, 0, 0);  // draw x-axis
  stroke(128); line(0, 0, 0, 0, 30, 0);  // draw y-axis
  stroke(192); line(0, 0, 0, 0, 0, 30);  // draw z-axis
  postDraw();
}
void draw() {
  preDraw();
  for (int i = 0; i<lines.length; i++) {
    lines[i].update();
  }
  postDraw();
}
void keyPressed() {
  switch (key) {
  case '+':  zoom += 0.2; break;  // zoom in
  case '-':  zoom -= 0.2; break;  // zoom out
  case ' ':  break;  // clear screen
  case '4':  rotY -= PI / 12; break;  // rotate left or right
  case '6':  rotY += PI / 12; break;  // rotate right or left
  case '8':  rotX -= PI / 12; break;  // rotate up or down
  case '2':  rotX += PI / 12; break;  // rotate down or up
  default :  println("key[" + keyCode + ", " + key + "]"); return;
  }
  clearScreen();
  println("zoom:" + zoom + " rot:(" + rotX + ", " + rotY + ")");
}

class RosslerLine {
  float a = 0.2, b = 0.2, c = 5.7;
  float x = 1.0, y = 1.0, z = 1.0;
  float dt = 0.0015;
  int stepPerFrame = 35;
  int col;
  RosslerLine(float a, float b, float c, float x, float y, float z, int col) {
    this.x = x; this.y = y; this.z = z;
    this.a = a; this.b = b; this.c = c;
    this.col = col;
  }
  void update() {
    stroke(col);
    float x0 = x, y0 = y, z0 = z;
    for (int i = 0; i < stepPerFrame; i++) {
      float dx = ( - y - z ) * dt;
      float dy = ( x + a * y ) * dt;
      float dz = ( b + z * (x - c) ) * dt;
      x += dx; y += dy; z += dz;
    }
    line(x0, y0, z0, x, y, z);
  }
}