Latest comments for language 'D' on doukaku.org

ika's comment on 漢数字で九九の表

修正.

private import std.stdio : write, writeln;
private import std.string : repeat;
private import std.typecons : defineEnum;

mixin(defineEnum!("数", uint, "〇", "一", "二", "三", "四", "五",
                              "六", "七", "八", "九", "十"));
enum 空白 = "　";

dstring toDString(string s) {
    dstring ds;
    foreach(dchar dc; s) ds ~= dc;
    return ds;
}

dstring 文字列化(数 かず) {
    string もじれつ;
    while(かず) {
        もじれつ = enumToString(かず % 数.十) ~ もじれつ;
        かず /= 数.十;
    }
    return もじれつ.toDString;
}

void main() {
    foreach(い; 数.一 .. 数.十) {
        foreach(ろ; 数.一 .. 数.十) {
            auto もじれつ = 文字列化(い * ろ);
            write(空白.repeat(数.三 - もじれつ.length), もじれつ);
        }
        writeln();
    }
}

[ D ] [ download code ] ]

ika's comment on 漢数字で九九の表

漢数字で九九の表 (Nested Flatten)

defineEnumは列挙型と、列挙型<=>文字列を相互変換する関数を定義するテンプレートです。

private import std.stdio : write, writeln;
private import std.string : repeat;
private import std.typecons : defineEnum;
private import std.utf : toUTF32;

mixin(defineEnum!("数", uint, "〇", "一", "二", "三", "四", "五",
                              "六", "七", "八", "九", "十"));
enum 空白 = "　";

dstring 文字列化(数 かず) {
    string もじれつ;
    while(かず) {
        もじれつ = enumToString(かず % 数.十) ~ もじれつ;
        かず /= 数.十;
    }
    return もじれつ.toUTF32;
}

void main() {
    foreach(い; 数.一 .. 数.十) {
        foreach(ろ; 数.一 .. 数.十) {
            auto もじれつ = 文字列化(い * ろ);
            write(空白.repeat(3 - もじれつ.length), もじれつ);
        }
        writeln();
    }
}

[ D ] [ download code ] ]

ika's comment on 疑似並行処理

疑似並行処理 (Nested Flatten)

D2.020から言語コアと標準ライブラリが分離されました。なぜか言語コアのほうに含まれているThreadGroupなるユーティリティクラスを使ってみました。

private import core.thread, std.stdio;

void main() {
    auto threads = new ThreadGroup;
    threads.create({
        foreach(x; "0123456789") {
            write(x);
            Thread.yield;
        }
    });
    threads.create({
        foreach(x; "abcdefghij") {
            write(x);
            Thread.yield;
        }
    });
    threads.joinAll;
}

[ D ] [ download code ] ]

ika's comment on 2^i * 3^j * 5^k なる整数

2^i * 3^j * 5^k なる整数 (Nested Flatten)

因数分解する方針で。

import std.stdio;

struct HammingNumbers {
    static bool isHammingNumber(uint n) {
        static bool[uint] memo;
        
        if(n == 1) return true;
        if(auto p = n in memo) return *p;
        
        if(n % 2 == 0)
            return memo[n] = isHammingNumber(n / 2);
        if(n % 3 == 0)
            return memo[n] = isHammingNumber(n / 3);
        if(n % 5 == 0)
            return memo[n] = isHammingNumber(n / 5);
        return memo[n] = false;
    }
    
    static int opApply(int delegate(ref const(size_t), ref const(uint)) dg) {
        size_t i = 0;
        uint n = 1;
        while(true) {
            if(isHammingNumber(n)) {
                if(auto result = dg(i, n))
                    return result;
                i++;
            }
            n++;
        }
    }
}

void main(){
    foreach(i, n; HammingNumbers) {
        if(i == 100) break;
        writeln(i, ": ", n);
    }
}

[ D ] [ download code ] ]

ika's comment on 不動点演算子

不動点演算子 (Nested Flatten)

テンプレート引数の推論を使って型無しラムダっぽく。

import std.stdio;

void main() {    
    auto Y = new class {
        auto opCall(_)(_ f) {
            return (new class {
                auto opCall(_)(_ g) {
                    return new class {
                        auto opCall(_)(_ x) {
                            return f(g(g))(x);
                        }
                    };
                }
            })(new class {
                auto opCall(_)(_ g) {
                    return new class {
                        auto opCall(_)(_ x) {
                            return f(g(g))(x);
                        }
                    };
                }
            });
        };
    };
    
    auto F = new class {
        auto opCall(_)(_ f) {
            return new class {
                auto opCall(_)(_ x) {
                    if (x == 0) {
                        return cast(_)1;
                    } else {
                        return x * f(x - 1);
                    }
                }
            };
        }
    };

    auto factorial = Y(F);
    writeln("fact(5) = ", factorial(10));
    writeln("fact(5) = ", factorial(20L));
}

[ D ] [ download code ] ]

匿名's comment on テスト

テスト (Nested Flatten)

テスト投稿

int main()
{
    printf("test\n");
    return 0;
}

[ D ] [ download code ] ]

ika's comment on LL Golf Hole 7 - バイト数を読みやすくする

LL Golf Hole 7 - バイト数を読みやすくする (Nested Flatten)

C++のを真似ようと思ったのですが、なんだか普通になってしまいました。入力はリテラル、出力はコンパイラメッセージで。

出力:

123
234.5k
345.6M
456.7G
567.8T
d202.d(39): static assert  "done!"

static import std.metastrings;

struct None { enum Symbol = "",  Base = 1;    }
struct Kilo { enum Symbol = "k", Base = 1e+3; }
struct Mega { enum Symbol = "M", Base = 1e+6; }
struct Giga { enum Symbol = "G", Base = 1e+9; }
struct Tera { enum Symbol = "T", Base = 1e12; }

template SIPrefix(long n) {
    static if(n < Kilo.Base)
        alias None SIPrefix;
    else static if(n < Mega.Base)
        alias Kilo SIPrefix;
    else static if(n < Giga.Base)
        alias Mega SIPrefix;
    else static if(n < Tera.Base)
        alias Giga SIPrefix;
    else
        alias Tera SIPrefix;
}

template SIFormat(long n) {
    enum SIFormat = ToString!(n / SIPrefix!(n).Base) ~ SIPrefix!(n).Symbol;
}

private template ToString(real x) {
    enum ToString = ToString!(cast(long)x) ~ "." ~ ToString!(cast(long)(x * 10))[$ - 1];
}
private template ToString(long x) {
    enum ToString = std.metastrings.ToString!(x);
}


pragma(msg, SIFormat!(123));
pragma(msg, SIFormat!(234567));
pragma(msg, SIFormat!(345678901));
pragma(msg, SIFormat!(456789012345));
pragma(msg, SIFormat!(567890123456789));

static assert(false, "done!"); // コンパイル終了

[ D ] [ download code ] ]

Dubhead's comment on 文字列型日時ののN秒後時間取得

文字列型日時ののN秒後時間取得 (Nested Flatten)

使用例も書かないとダメですね。

import std.conv;
import std.date;
import std.stdio;

string DateEx(string datetime, int tdelta_in_secs)
{
    d_time t = std.date.parse(datetime);
    d_time new_datetime = t + tdelta_in_secs * std.date.TicksPerSecond;
    return std.date.toString(new_datetime);
}
unittest {
    assert(DateEx("Mon Sep 01 13:00:00 GMT+0900 2008", -3600) ==
        "Mon Sep 01 12:00:00 GMT+0900 2008");
    assert(DateEx("Mon Sep 01 13:00:00 GMT+0900 2008", 3600) ==
        "Mon Sep 01 14:00:00 GMT+0900 2008");
}

void main(string[] args)
{
    string datetime;
    int tdelta_in_secs;
    if (args.length == 3) {
        datetime = args[1];
        tdelta_in_secs = toInt(args[2]);
    }
    else {
        d_time now = std.date.getUTCtime;
        datetime = std.date.toString(now);
        tdelta_in_secs = toInt(args[1]);
    }
    writefln("%s", DateEx(datetime, tdelta_in_secs));
}

// eof

[ D ] [ download code ] ]

Dubhead's comment on 文字列型日時ののN秒後時間取得

文字列型日時ののN秒後時間取得 (Nested Flatten)

D 2.0 + Phobos。

import std.conv;
import std.date;
import std.stdio;

string DateEx(string datetime, int tdelta_in_secs)
{
    d_time t = std.date.parse(datetime);
    d_time new_datetime = t + tdelta_in_secs * std.date.TicksPerSecond;
    return std.date.toString(new_datetime);
}

void main(string[] args)
{
    string datetime;
    int tdelta_in_secs;
    if (args.length == 3) {
        datetime = args[1];
        tdelta_in_secs = toInt(args[2]);
    }
    else {
        d_time now = std.date.getUTCtime;
        datetime = std.date.toString(now);
        tdelta_in_secs = toInt(args[1]);
    }
    writefln("%s", DateEx(datetime, tdelta_in_secs));
}

// eof

[ D ] [ download code ] ]

ika's comment on LL Golf Hole 8 - 横向きのピラミッドを作る

LL Golf Hole 8 - 横向きのピラミッドを作る (Nested Flatten)

標準入力から。

import std.stdio, std.conv, std.string;

void main() {
    int n = to!(uint)(chomp(readln));
    foreach(i; 1..n*2)
        writeln("*".repeat(i<n?i:2*n-i));
}

[ D ] [ download code ] ]

ika's comment on LL Golf Hole 5 - 最上位の桁を数え上げる

LL Golf Hole 5 - 最上位の桁を数え上げる (Nested Flatten)

標準入力から。

この手の文字列操作はガーベジコレクタのおかげでたやすくできます。

import std.stdio, std.string;

void main() {
    auto t = chomp(readln), s = "0".dup;
    while(s.length < t.length || s <= t) {
        writeln(s);
        
        if(s[0] < '9') {
            s[0]++;
        } else {
            s = "10" ~ s[1 .. $];
        }
    }
}

[ D ] [ download code ] ]

ika's comment on LL Golf Hole 6 - 10進数を2進数に基数変換する

LL Golf Hole 6 - 10進数を2進数に基数変換する (Nested Flatten)

標準入力から一行読み込んで変換。

import std.stdio, std.conv, std.string;

void main() {
    writefln("%b",to!(int)(strip(readln)));
}

[ D ] [ download code ] ]

ika's comment on LL Golf Hole 4 - 文章から単語の索引を作る

LL Golf Hole 4 - 文章から単語の索引を作る (Nested Flatten)

文章はコンパイル時に文字列リテラルとして取り込むので、dmdの-Jオプションでgpl.txtのあるディレクトリを指定してください。

private import std.stdio, std.string, std.regexp;

auto text = import("gpl.txt");

void main() {
    int[][string] dict;
    auto re = RegExp(r"[\w-]+");
    foreach(i, line; text.splitlines()) {
        foreach(m; re.search(line)) {
            dict[m[0].tolower()] ~= i + 1;
        }
    }
    writeln(dict);
}

[ D ] [ download code ] ]

ika's comment on LL Golf Hole 3 - 13日の金曜日を数え上げる

LL Golf Hole 3 - 13日の金曜日を数え上げる (Nested Flatten)

private import std.stdio, std.date;

enum Friday = 5;

void main(){
    auto count = 0;
    foreach(day; Day(getUTCtime) .. MakeDay(2014, 1, 1)) {
        auto date = MakeDate(day, 0);
        if(WeekDay(date) == Friday && DateFromTime(date) == 13) {
            writefln("%04d-%02d-%02d", YearFromTime(date), MonthFromTime(date) + 1, DateFromTime(date));
            ++count;
        }
    }
    writeln(count);
}

[ D ] [ download code ] ]

ika's comment on LL Golf Hole 2 - 文字列に含まれる単語の最初の文字を大文字にする

LL Golf Hole 2 - 文字列に含まれる単語の最初の文字を大文字にする (Nested Flatten)

private import std.string, std.regexp;

string totitle(in string str) {
    return str.sub(r"\b[a-z]", (RegExp m){return m[0].toupper();}, "g");
}

unittest {
    assert("LL future".totitle() == "LL Future");
    assert("LL day and night".totitle() == "LL Day And Night");
}

[ D ] [ download code ] ]

ika's comment on 循環関数

循環関数 (Nested Flatten)

int modular(int n, int low, int high) {
    return low + (n + high - low + 1) % (high - low + 1);
}

unittest {
    assert(modular(0,100,200)   == 100);
    assert(modular(50,100,200)  == 150);
    assert(modular(100,100,200) == 200);
    assert(modular(101,100,200) == 100);
    assert(modular(-1,100,200)  == 200);
    assert(modular(1,-5,200)    ==  -4);
    assert(modular(-500,-5,-1)  ==  -5);
}

[ D ] [ download code ] ]

ika's comment on 2次元ランダムウォーク

2次元ランダムウォーク (Nested Flatten)

出力はSVGにしてみました。

private import std.stdio, std.math, std.random;

void main() {
    write(`<?xml version="1.0"?>
<!DOCTYPE svg PUBLIC "-//W3C//DTD SVG 1.1//EN" "http://www.w3.org/Graphics/SVG/1.1/DTD/svg11.dtd">
<svg xmlns="http://www.w3.org/2000/svg" version="1.1" width="600" height="600">
<title>ランダムウォーク</title>
<g transform="translate(300,300)">
<circle style="fill:blue" cx="0" cy="0" r="5"/>
<path style="fill:none; stroke:black; stroke-width:1" d="M 0 0`);

    auto rgen = Random(unpredictableSeed);
    auto uniform = UniformDistribution!(real)(0, PI * 2);
    foreach(_; 0 .. 10000) {
        auto angle = uniform.next(rgen);
        auto move = expi(angle) * 10;
        writef(` l %.2f %.2f`, move.re, move.im);
    }

    write(`"/>
</g>
</svg>`);
}

[ D ] [ download code ] ]

ika's comment on LL Golf Hole 1 - tinyurl.comを使ってURLを短縮する

LL Golf Hole 1 - tinyurl.comを使ってURLを短縮する (Nested Flatten)

private import std.stdio, std.string, std.socket, std.socketstream;

void main() {
    auto s = new SocketStream(new TcpSocket(new InternetAddress("tinyurl.com", 80)));
    scope(exit) s.close;
    
    s.writeString("GET /api-create.php?url=http://ll.jus.or.jp/2008/info/xgihyo HTTP/1.1\r\nHost: tinyurl.com\r\n\r\n");
    foreach(char[] line; s) if(line.startsWith("http://")) writeln(line);
}

[ D ] [ download code ] ]

ika's comment on 環境変数の取得

環境変数の取得 (Nested Flatten)

変数名から値を得るだけなら、getenv 関数があります。

private import std.stdio, std.process;

void main() {
    writeln(getenv("PATH"));
}

[ D ] [ download code ] ]

Dubhead's comment on 環境変数の取得

環境変数の取得 (Nested Flatten)

D 2.0 + 標準ライブラリ (Phobos)、Linuxで動作確認。連想配列を作ってしまう方針で。
Phobosには環境変数APIが無いので、Cの environ(7) を直接呼び出します。
C文字列をDのstringに変換する処理が面倒ですね。もっとうまいやり方があるような気がする...

import std.stdio;
import std.string;
import std.c.linux.linux: environ;
import std.c.string: strlen;

void main()
{
    char** p;
    string[string] envAA;
    for (p = environ; *p != null; p++) {
        char[] key_and_value = (*p)[0 .. strlen(*p)];    // "FOO=BAR"
        int iEqual = key_and_value.find('=');    // index to '='
        string key = cast(string)(key_and_value[0 .. iEqual]);
        string value = cast(string)(key_and_value[iEqual + 1 .. $]);
        envAA[key] = value;
    }
    envAA.rehash;

    foreach(key, value; envAA) {
        writefln("%s: %s", key, value);
    }
    writefln("PATH = %s", envAA["PATH"]);
}

[ D ] [ download code ] ]