Latest comments for language '秀丸マクロ' on doukaku.org

fujidig's comment on BFコンパイラー

一番手間がかかったのはgetcharの実装です。

begingroupundo;
gofiletop;
$code['>'] = "#ptr=#ptr+1;";
$code['<'] = "#ptr=#ptr-1;";
$code['+'] = "#buf[#ptr]=#buf[#ptr]+1;";
$code['-'] = "#buf[#ptr]=#buf[#ptr]-1;";
$code['.'] = "insert char(#buf[#ptr]);";
$code[','] = "call get;";
$code['['] = "while(#buf[#ptr]){";
$code[']'] = "}";
#isUsedGetchar = false;
while( code != eof ) {
    if( code == ',' ) #isUsedGetchar = true;
    insert $code[code];
    delete;
}
if( #isUsedGetchar ) {
    insert "endmacro;get:if($get==\"\"&&#c<=0)$get=input(\"入力\");#c=ascii($get);if($get==\"\")#c=-1;$get=rightstr($get,strlen($get)-strlen(char(#c)));#buf[#ptr]=#c;return;";
}
endgroupundo;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on ビンゴの結果を整形表示

ビンゴの結果を整形表示 (Nested Flatten)

    call srand tickcount;
    call bingo 35;
    endmacro;

bingo:
    ##i = 0;
    while( ##i < ##1 ) {
        ##dest[##i] = ##i + 1;
        ##i = ##i + 1;
    }
    ##i = 0;
    while( ##i < ##1 ) {
        call rand;
        ##r = ##return % ( ##1 - ##i ) + ##i;
        ##tmp = ##dest[##r];
        ##dest[##r] = ##dest[##i];
        ##dest[##i] = ##tmp;
        ##i = ##i + 1;
    }
    ##keta = strlen( str( ##1 ) );
    ##i = 0;
    while( ##i < ##1 ) {
        ##next = ##i + 10;
        if ( ##next > ##1 ) {
            ##next = ##1;
        }
        ##ii = ##i;
        while( ##ii < ##next ) {
            if ( ##ii > ##i ) {
                insert " ";
            }
            call KetaSoroe ##ii+1, ##keta;
            insert $$return;
            ##ii = ##ii + 1;
        }
        insert "\n";
        ##ii = ##i;
        while( ##ii < ##next ) {
            if ( ##ii > ##i ) {
                insert " ";
            }
            call KetaSoroe ##dest[##ii], ##keta;
            insert $$return;
            ##ii = ##ii + 1;
        }
        insert "\n\n";
        ##i = ##next;
    }
    return;

KetaSoroe:
    ##i = ##2 - strlen( str( ##1 ) );
    $$result = "";
    if ( ##i >= 0 ) {
        while( ##i > 0 ) {
            $$result = $$result + " ";
            ##i = ##i - 1;
        }
    }
    $$result = $$result + str( ##1 );
    return $$result;

rand:
    #rand_x = #rand_x * 214013 + 2531011;
    if ( #rand_x < 0 ) {
        return ( ( #rand_x + 1 ) / 65536 - 1 ) & 32767;
    }
    return #rand_x / 65536 & 32767;

srand:
    #rand_x = ##1;
    return;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 重複無し乱数

重複無し乱数 (Nested Flatten)

乱数を発生させる関数がなかったのでそこから実装。

HSP ( #4289 ) と同じ結果になるように Visual C++ の rand と同じアルゴリズム・定数を使いました。 #4289 と乱数の種を同じにしたら同じ結果になるでしょう。（ HSP の randomize の引数、秀丸マクロの srand サブルーチンの引数）

    call srand tickcount;
    call bingo 10;
    call bingo 3;
    call bingo 3;
    call bingo 10;
    endmacro;

bingo:
    ##i = 0;
    while( ##i < ##1 ) {
        ##dest[##i] = ##i + 1;
        ##i = ##i + 1;
    }
    ##i = 0;
    while( ##i < ##1 ) {
        call rand;
        ##r = ##return % ( ##1 - ##i ) + ##i;
        ##tmp = ##dest[##r];
        ##dest[##r] = ##dest[##i];
        ##dest[##i] = ##tmp;
        ##i = ##i + 1;
    }
    ##i = 0;
    while( ##i < ##1 ) {
        if ( ##i > 0 ) {
            insert " ";
        }
        insert str( ##dest[##i] );
        ##i = ##i + 1;
    }
    insert "\n";
    return;

rand:
    #rand_x = #rand_x * 214013 + 2531011;
    if ( #rand_x < 0 ) {
        return ( ( #rand_x + 1 ) / 65536 - 1 ) & 32767;
    }
    return #rand_x / 65536 & 32767;

srand:
    #rand_x = ##1;
    return;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 文字列のセンタリング

文字列のセンタリング (Nested Flatten)

    if ( getconfig( "AutoAdjustOrikaeshi" ) == 2 ) {
        #width = windowwidth;
    } else {
        #width = getconfig( "Orikaeshi" );
    }
    disabledraw;
    begingroupundo;
    if ( !selecting ) {
        selectall;
    }
    #i = seltoplineno;
    #end = selendlineno;
    escape;
    while( #i <= #end ) {
        movetolineno 1, #i;
        #margin = #width - linelen2;
        if ( #margin >= 0 ) {
            #j = #margin / 2;
            while( #j > 0 ) {
                insert " ";
                #j = #j - 1;
            }
        } else {
            while( linelen2 > #width ) {
                golineend2;
                backspace;
                if ( !linelen2 > #width ) {
                    break;
                }
                golinetop2
                delete;
            }
        }
        #i = #i + 1;
    }
    endgroupundo;
    enabledraw;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 文字列のセンタリング

文字列のセンタリング (Nested Flatten)

    begingroupundo;
    if ( getconfig( "AutoAdjustOrikaeshi" ) == 2 ) {
        #width = windowwidth;
    } else {
        #width = getconfig( "Orikaeshi" );
    }
    if ( !selecting ) {
        #top = 1;
        #end = linecount2;
    } else {
        #top = seltoplineno;
        #end = selendlineno;
        escape;
    }
    #i = #top;
    while( #i <= #end ) {
        movetolineno 1, #i;
        #margin = #width - linelen2;
        if ( #margin >= 0 ) {
            #j = #margin / 2;
            $margin = "";
            while( #j > 0 ) {
                $margin = $margin + " ";
                #j = #j - 1;
            }
            insert $margin;
        } else {
            beginsel;
            movetolineno linelen2 + 1, #i;
            $text = gettext( seltopx, seltopy, selendx, selendy, 1 );
            delete;
            call cutstr, $text, #width;
            insert $$return;
        }
        #i = #i + 1;
    }
    endgroupundo;
    endmacro;

cutstr:
    $$src = $$1;
    ##width = ##2;
    if ( ##width < 0 ) {
        ##width = 0;
    }
    if ( ##width > strlen( $$src ) ) {
        ##width = strlen( $$src );
    }
    ##start = strlen( $$src ) - ##width;
    ##end = strlen( $$src ) + ##width;
    ##i = 0;
    $$dest = "";
    $$left = "";
    $$right = "";
    while( ##i * 2 < ##end ) {
        ##char = ascii( $$src );
        ##bytes = strlen( char( ##char ) );
        if ( ##i * 2 < ##start ) {
            $$left = char( ##char );
        }
        if ( ( ( ##i + ##bytes ) * 2 > ##end ) && ( $$right == "" ) ) {
            $$right = char( ##char );
        }
        if ( ( ##i * 2 >= ##start ) && ( ( ##i + ##bytes ) * 2 <= ##end ) ) {
            $$dest = $$dest + char( ##char );
        }
        $$src = rightstr( $$src, strlen( $$src ) - ##bytes );
        ##i = ##i + ##bytes;
    }
    if ( $$right == "" ) {
        $$right = char( ascii( $$src ) );
    }
    if ( strlen( $$dest ) >= ##width ) {
        return $$dest;
    }
    if ( ( strlen( $$left + $$dest ) <= ##width ) && ( $$left != "" ) ) {
        return $$left + $$dest;
    }
    if ( ( strlen( $$dest + $$right ) <= ##width ) && ( $$right != "" ) ) {
        return $$dest + $$right;
    }
    return $$dest;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 文字列のセンタリング

文字列のセンタリング (Nested Flatten)

文字列として取得して整形。

    begingroupundo;
    if ( getconfig( "AutoAdjustOrikaeshi" ) == 2 ) {
        #width = windowwidth;
    } else {
        #width = getconfig( "Orikaeshi" );
    }
    if ( !selecting ) {
        selectall;
    } else {
        #l1 = seltoplineno;
        #l2 = selendlineno;
        movetolineno 1, #l1;
        beginsel;
        movetolineno 1, #l2;
        movetolineno linelen2 + 1, #l2;
        endsel;
    }
    $text = gettext( seltopx, seltopy, selendx, selendy, 1 );
    delete;
    call center $text, #width;
    insert $$return;
    endgroupundo;
    endmacro;

center:
    $$result = "";
    while( $$1 != "" ) {
        ##lineLen = strstr( $$1, "\x0d\x0a" );
        ##isLastLine = ##lineLen == -1;
        if ( ##isLastLine ) {
            ##lineLen = strlen( $$1 );
        }
        $$line = leftstr( $$1, ##lineLen );
        call center_line $$line, ##2;
        $$result = $$result + $$return;
        $$1 = rightstr( $$1, strlen( $$1 ) - ##lineLen );
        if ( !##isLastLine ) {
            $$1 = rightstr( $$1, strlen( $$1 ) - strlen( "\x0d\x0a" ) );
            $$result = $$result + "\n";
        }
    }
    return $$result;

center_line:
    ##margin = ##2 - strlen( $$1 );
    if ( ##margin >= 0 ) {
        $$result = "";
        ##i = ##margin / 2;
        while( ##i > 0 ) {
            $$result = $$result + " ";
            ##i = ##i - 1;
        }
        $$result = $$result + $$1;
    } else {
        ##idx = -##margin / 2;
        call midstr2, $$1, ##idx, ##2;
        $$result = $$return;
        // ±1バイトとる範囲をずらして、その中から一番長いテキストをとる
        if ( strlen( $$result ) < ##2 ) {
            call midstr2, $$1, ##idx + 1, ##2;
            if ( strlen( $$return ) > strlen( $$result ) ) {
                $$result = $$return;
            }
            if ( strlen( $$result ) < ##2 ) {
                call midstr2, $$1, ##idx - 1, ##2;
                if ( strlen( $$return ) > strlen( $$result ) ) {
                    $$result = $$return;
                }
            }
        }
    }
    return $$result;

midstr2: // マルチバイトを考慮した midstr
    $$src = $$1;
    ##idx = ##2;
    ##len = ##3;
    if ( ##idx < 0 ) {
        ##idx = 0;
    }
    if ( ##idx > strlen( $$src ) ) {
        ##idx = strlen( $$src );
    }
    if ( ##len < 0 ) {
        ##len = 0;
    }
    if ( ##len > strlen( $$src ) - ##idx ) {
        ##len = strlen( $$src ) - ##idx ;
    }
    
    ##end = ##idx + ##len;
    ##i = 0;
    $$dest = "";
    while( ##i < ##end ) {
        ##char = ascii( rightstr( $$src, strlen( $$src ) - ##i ) );
        ##byte = strlen( char( ##char ) );
        if ( ( ##i >= ##idx ) && ( ##i + ##byte <= ##end ) ) {
            $$dest = $$dest + char( ##char );
        }
        ##i = ##i + ##byte;
    }
    return $$dest;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 税込み価格への修正

税込み価格への修正 (Nested Flatten)

searchdown2 で。

    disabledraw;
    begingroupundo;
    gofiletop;
    while( true ) {
        searchdown2 "[0-9]", regular;
        if( !result ) {
            break;
        }
        #figX = x;
        #figY = y;
        searchdown "[^0-9]", regular;
        if( !result ) {
            gofileend;
        }
        #figure = val( gettext( #figX, #figY, x, y ) );
        beginsel;
        moveto #figX, #figY;
        insert str( #figure * 105 / 100 );
    }
    endgroupundo;
    enabledraw;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on /コメント/を取り除く

/*コメント*/を取り除く (Nested Flatten)

searchdown2 を使えばもっと簡潔にできましたね。

    disabledraw;
    begingroupundo;
    gofiletop;
    while( true ) {
        searchdown2 "/*";
        if ( !result ) {
            break;
        }
        #commentStartX = x;
        #commentStartY = y;
        movetolineno column + 1 + strlen( "/*" ), lineno;
        searchdown2 "*/";
        if( !result ) {
            gofileend;
        }
        movetolineno column + 1 + strlen( "*/" ), lineno;
        beginsel;
        moveto #commentStartX, #commentStartY;
        delete;
    }
    endgroupundo;
    enabledraw;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 文字列からの情報抽出

文字列からの情報抽出 (Nested Flatten)

    $output = "";
    disabledraw;
    gofiletop;
    while( true ) {
        searchdown2 "[A-Za-z]+(-hidden)?(-(small|big))?\\.[A-Za-z]+", regular;
        if ( !result ) {
            break;
        }
        #x = x;
        #y = y;
        searchdown "[-.]", regular;
        $name = gettext( #x, #y, x, y );
        $size = "normal";
        $hidden = "False";
        while( code == '-' ) {
            movetolineno column + 1 + strlen( "-" ), lineno;
            #x = x;
            #y = y;
            searchdown "[-.]", regular;
            $option = gettext( #x, #y, x, y );
            if ( $option == "big" ) {
                $size = "big";
            }
            if ( $option == "small" ) {
                $size = "small";
            }
            if ( $option == "hidden" ) {
                $hidden = "True";
            }
        }
        movetolineno column + 1 + strlen( "." ), lineno;
        #x = x;
        #y = y;
        searchdown "[^A-Za-z]", regular;
        if ( !result ) {
            gofileend;
        }
        $ext = gettext( #x, #y, x, y );
        $output = $output + "name:'" + $name + "', ext:'" + $ext+"', size: " + $size+" hidden: " + $hidden + "\n";
    }
    enabledraw;
    newfile;
    insert $output;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on /コメント/を取り除く

/*コメント*/を取り除く (Nested Flatten)

開いている文書から取り除く。

    disabledraw;
    begingroupundo;
    gofiletop;
    while( true ) {
        if ( gettext2( column, lineno, column + strlen( "/*" ), lineno ) != "/*" ) {
            searchdown "/*";
            if ( !result ) {
                break;
            }
        }
        #commentStartX = x;
        #commentStartY = y;
        movetolineno column + 1 + strlen( "/*" ), lineno;
        if ( gettext2( column, lineno, column + strlen( "*/" ), lineno ) != "*/" ) {
            searchdown "*/";
            if( !result ) {
                gofileend;
            }
        }
        movetolineno column + 1 + strlen( "*/" ), lineno;
        #commentEndX = x;
        #commentEndY = y;
        beginsel;
        moveto #commentStartX, #commentStartY;
        delete;
    }
    endgroupundo;
    enabledraw;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 税込み価格への修正

税込み価格への修正 (Nested Flatten)

開いている文書から変換。
「与えられた文字列の中から見つけ出し、変更した文字列を返す関数を作る」には沿っていませんが、この方が秀丸マクロらしいと思います。

    disabledraw;
    begingroupundo;
    gofiletop;
    while( true ) {
        if ( code < '0' || code > '9' ) {
            searchdown "[0-9]", regular;
            if( !result ) {
                break;
            }
        }
        #figX = x;
        #figY = y;
        searchdown "[^0-9]", regular;
        if( !result ) {
            gofileend;
        }
        #figure = val( gettext( #figX, #figY, x, y ) );
        beginsel;
        moveto #figX, #figY;
        delete;
        insert str( #figure * 105 / 100 );
    }
    endgroupundo;
    enabledraw;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 税込み価格への修正

税込み価格への修正 (Nested Flatten)

    call IncludeTax "ダイコン150円、ハクサイ120円、ジャガイモ30円";
    message $$return;
    endmacro;

IncludeTax:
    $$figure = "";
    $$result = "";
    while( $$1 != "" ) {
        ##char = ascii( $$1 );
        if ( ##char >= '0' && ##char <= '9' ) {
            $$figure = $$figure + char( ##char );
        } else {
            if ( $$figure != "" ) {
                $$result = $$result + str( val( $$figure ) * 105 / 100 );
                $$figure = "";
            }
            $$result = $$result + char( ##char );
        }
        
        $$1 = rightstr( $$1, strlen( $$1 ) - strlen( char( ##char ) ) );
    }
    if ( $$figure != "" ) {
        $$result = $$result + str( val( $$figure ) * 105 / 100 );
        $$figure = "";
    }
    return $$result;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 文字列の反転

文字列の反転 (Nested Flatten)

unichar 、 unicode でなく、 char と ascii でもマルチバイト文字に対応していましたので以下のコードでも動きました。

    call reverse_string "Hello";
    message $$return;
    call reverse_string "こんにちは";
    message $$return;
    call reverse_string "濁点(だくてん)";
    message $$return;
    endmacro;

reverse_string:
    $$result = "";
    while( $$1 != "" ) {
        $$char = char( ascii( $$1 ) );
        $$result = $$char + $$result;
        $$1 = rightstr( $$1, strlen( $$1 ) - strlen( $$char ) );
    }
    return $$result;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 変形Fizz-Buzz問題

変形Fizz-Buzz問題 (Nested Flatten)

    #i = 1;
    #a[0] =  1; $b[0] = "hoge";
    #a[1] =  3; $b[1] = "Fizz";
    #a[2] =  5; $b[2] = "Buzz";
    #a[3] = 15; $b[3] = "FizzBuzz";
    while( #i <= 20 ) {
        call KetaSoroe #i, 2;
        insert $$return + ":";
        #j = 3;
        while( #j >= 0 ) {
            if( #i % #a[#j] == 0 ) {
                insert $b[#j];
                break;
            }
            #j = #j - 1;
        }
        insert "\n";
        #i = #i + 1;
    }
    endmacro;

KetaSoroe:
    ##i = ##2 - strlen( str( ##1 ) );
    $$result = "";
    if ( ##i >= 0 ) {
        while( ##i > 0 ) {
            $$result = $$result + " ";
            ##i = ##i - 1;
        }
    }
    $$result = $$result + str( ##1 );
    return $$result;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on ダブル完全数

ダブル完全数 (Nested Flatten)

処理速度がありえないくらい遅いです...

    #i = 2;
    while( #i <= 10000 ) {
        call IsDoubleCompleteNumber #i;
        if ( ##return ) {
            insert str( #i ) + "\n";
        }
        #i = #i + 1;
    }
    insert "以上";
    endmacro;

IsDoubleCompleteNumber:
    ##sum = 0;
    ##i = ##1 - 1;
    while( ##i >= 1 ) {
        if ( ( ##1 % ##i ) == 0 ) {
            ##sum = ##sum + ##i;
        }
        ##i = ##i - 1;
    }
    return ( ##sum == ( ##1 * 2 ) );

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 文字列の反転

文字列の反転 (Nested Flatten)

    call reverse_string "Hello";
    message $$return;
    call reverse_string "こんにちは";
    message $$return;
    call reverse_string "濁点(だくてん)";
    message $$return;
    endmacro;

reverse_string:
    $$result = "";
    while( $$1 != "" ) {
        $$char = unichar( unicode( $$1 ) );
        $$result = $$char + $$result;
        $$1 = rightstr( $$1, strlen( $$1 ) - strlen( $$char ) );
    }
    return $$result;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 与えられた数字のケタ数

与えられた数字のケタ数 (Nested Flatten)

    #val = val( input( "数値を入力", "2469" ) );
    if ( #val < 0 ) {
        #val = -#val;
    }
    #keta = strlen( str( #val ) );
    message str( #keta ) + "桁";
    $kurai = "1";
    #i = #keta - 1;
    while( #i > 0 ) {
        $kurai = $kurai + "0";
        #i = #i - 1;
    }
    message "最大桁の位："+$kurai;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on アルファベットの繰り上がり

アルファベットの繰り上がり (Nested Flatten)

    #i = 1;
    while( #i <= 100 ) {
        call excelalpha #i;
        if ( #i != 1 ) {
            insert ", ";
        }
        insert $$return;
        #i = #i + 1;
    }
    endmacro;

excelalpha:
    $$result = "";
    while ( ##1 != 0 ) {
        ##1 = ##1 - 1;
        $$result = char( ##1 % 26 + 'A' ) + $$result;
        ##1 = ##1 / 26;
    }
    return $$result;

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on リストを逆順に表示

リストを逆順に表示 (Nested Flatten)

    #list[0] = 1;
    #list[1] = 2;
    #list[2] = 3;
    #list[3] = 4;
    #list[4] = 5;

    #i = 4;
    while( #i >= 0 ) {
        message str( #list[#i] );
        #i = #i - 1;
    }

[ 秀丸マクロ ] [ download code ] ]

fujidig's comment on 倍数になる13進数

倍数になる13進数 (Nested Flatten)

    #i = 10;
    while( true ) {
        call convert #i;
        if ( ##return == ( #i * 2 ) ) {
            break;
        }
        #i = #i + 1;
    }
    message str( #i );
    endmacro;

convert:
    $$val = str( ##1 );
    ##result = 0;
    ##i = 0;
    while( ##i < strlen( $$val ) ) {
        ##result = ##result * 13 + val( midstr( $$val, ##i, 1 ) );
        ##i = ##i + 1;
    }
    return ##result;

[ 秀丸マクロ ] [ download code ] ]

Latest comments for language '秀丸マクロ' on doukaku.org

fujidig's comment on BFコンパイラー

fujidig's comment on ビンゴの結果を整形表示

fujidig's comment on 重複無し乱数

fujidig's comment on 文字列のセンタリング

fujidig's comment on 文字列のセンタリング

fujidig's comment on 文字列のセンタリング

fujidig's comment on 税込み価格への修正

fujidig's comment on /*コメント*/を取り除く

fujidig's comment on 文字列からの情報抽出

fujidig's comment on /*コメント*/を取り除く

fujidig's comment on 税込み価格への修正

fujidig's comment on 税込み価格への修正

fujidig's comment on 文字列の反転

fujidig's comment on 変形Fizz-Buzz問題

fujidig's comment on ダブル完全数

fujidig's comment on 文字列の反転

fujidig's comment on 与えられた数字のケタ数

fujidig's comment on アルファベットの繰り上がり

fujidig's comment on リストを逆順に表示

fujidig's comment on 倍数になる13進数

fujidig's comment on /コメント/を取り除く

fujidig's comment on /コメント/を取り除く