Latest comments for language 'XSLT' on doukaku.org

turugina's comment on 文字列型日時ののN秒後時間取得

条件2を満たしてなかった。ので、修正。

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:my="uri:ja.doukaku.org:my-functions"
  exclude-result-prefixes="my"
  >

  <xsl:output method="text" />

  <xsl:template match="/" >
    <xsl:value-of select="my:DateEx('2008-09-01T10:02:38', -1)"/>
  </xsl:template>

  <xsl:function name="my:DateEx" as="xs:string">
    <xsl:param name="dstr" as="xs:string" />
    <xsl:param name="sec" as="xs:integer" />

    <xsl:sequence select="xs:string(
      xs:dateTime($dstr) +
      xs:dayTimeDuration(
        fn:concat(
          (if($sec&lt;0)then'-'else''),
          'PT', xs:string(fn:abs($sec)), 'S'
          )
        )
      )" />
  </xsl:function>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on 文字列型日時ののN秒後時間取得

文字列型日時ののN秒後時間取得 (Nested Flatten)

入出力の日付文字列はISO8601形式です。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:my="uri:ja.doukaku.org:my-functions"
  exclude-result-prefixes="my"
  >

  <xsl:output method="text" />

  <xsl:template match="/" >
    <xsl:value-of select="my:DateEx('2008-09-01T10:02:38', 10000)"/>
  </xsl:template>


  <xsl:function name="my:DateEx" as="xs:string">
    <xsl:param name="dstr" as="xs:string" />
    <xsl:param name="sec" as="xs:integer" />

    <xsl:sequence select="xs:string(
      xs:dateTime($dstr) +
      xs:dayTimeDuration(fn:concat('PT',xs:string($sec),'S'))
      )" />
  </xsl:function>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 8 - 横向きのピラミッドを作る

LL Golf Hole 8 - 横向きのピラミッドを作る (Nested Flatten)

for expression を使ってみる。
451bytes, 実質444bytes

<transform version="2.0" xmlns="http://www.w3.org/1999/XSL/Transform" xmlns:y="y">
<output method="text"/><param name="n"/>
<template match="/"><value-of separator="&#xA;" select="y:f(1)"/></template>
<function name="y:f"><param name="i"/>
<sequence select="(y:g($i),if($i=$n)then()else(y:f($i+1),y:g($i)))"/>
</function><function name="y:g"><param name="i"/>
<sequence select="string-join((for$x in(1 to$i)return('*')),'')"/>
</function></transform>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 7 - バイト数を読みやすくする

LL Golf Hole 7 - バイト数を読みやすくする (Nested Flatten)

一応YiBまで対応(処理系が対応してればだけど.
変換対象のバイト数はスタイルシートパラメタnで与えます。
449bytes, 実質443bytes

<transform version="2.0" xmlns="http://www.w3.org/1999/XSL/Transform" xmlns:y="y">
<output method="text"/><param name="n"/>
<variable name="u" select="('B','KiB','MiB','GiB','TiB','PiB','EiB','ZiB','YiB')"/>
<template match="/"><value-of select="y:f($n,1)"/></template>
<function name="y:f"><param name="m"/><param name="i"/>
<sequence select="if($m&lt;1024)then($m,$u[$i])else
y:f(round-half-to-even($m div 1024,2),$i+1)"/>
</function></transform>

[ XSLT ] [ download code ] ]

turugina's comment on 除算・余剰を使わずに閏年

除算・余剰を使わずに閏年 (Nested Flatten)

そうか、その手が。。。

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  >

  <xsl:output method="text" />

  <xsl:template match="/" >
    <xsl:for-each select="1900 to 2100">
      <xsl:variable name="thisYear" as="xs:date"
        select="xs:date(fn:concat(xs:string(.), '-01-01'))" />
      <xsl:variable name="nextYear" as="xs:date"
        select="xs:date(fn:concat(xs:string(1+.), '-01-01'))" />
      <xsl:if test="fn:days-from-duration($nextYear - $thisYear)=366">
        <xsl:value-of select="." />
        <xsl:text> 年は閏年♪&#xA;</xsl:text>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 3 - 13日の金曜日を数え上げる

LL Golf Hole 3 - 13日の金曜日を数え上げる (Nested Flatten)

XSLTでは実行時時刻を取得する手段が標準で存在しないので、
お題の投稿日を「今日」ということにしてます。

一応「今日」が変わっても正しく計算できるようにして、
630 bytes.改行が7つ削れるので実質623bytes

<transform version="2.0"
xmlns="http://www.w3.org/1999/XSL/Transform"
xmlns:s="http://www.w3.org/2001/XMLSchema"
xmlns:f="http://www.w3.org/2005/xpath-functions"
xmlns:y="uri:ja.doukaku.org:my-functions">
<variable name="f" select="s:date('2008-08-05')"/>
<output method="text"/><template match="/">
<value-of separator=",">
<for-each select="0 to f:days-from-duration(s:date('2013-12-31')-$f)">
<variable name="d" select="$f+s:dayTimeDuration(f:concat('P',.,'D'))"/>
<sequence select="if(f:day-from-date($d)*(f:days-from-duration($d -s:date('1970-01-04'))mod 7)=65)then $d else()"/>
</for-each></value-of></template></transform>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 4 - 文章から単語の索引を作る

LL Golf Hole 4 - 文章から単語の索引を作る (Nested Flatten)

XSLTでも何とかできた。

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  >

  <xsl:output method="text" />

  <xsl:variable name="gpl" as="xs:string"
    select="unparsed-text('http://www.gnu.org/licenses/gpl.txt')" />

  <xsl:variable name="mid" as="element()">
    <xsl:element name="root">
      <xsl:for-each select="fn:tokenize($gpl, '\n')">
        <xsl:element name="line">
          <xsl:attribute name="no">
            <xsl:value-of select="position()" />
          </xsl:attribute>
          <xsl:for-each select="fn:tokenize(., '\W+')">
            <xsl:element name="word">
              <xsl:value-of select="fn:lower-case(.)" />
            </xsl:element>
          </xsl:for-each>
        </xsl:element>
      </xsl:for-each>
    </xsl:element>
  </xsl:variable>

  <xsl:template match="/" >
    <xsl:for-each select="fn:distinct-values($mid//word/text())">
      <xsl:sort data-type="text" />
      <xsl:variable name="t" as="xs:string" select="." />
      <xsl:value-of select="." />
      <xsl:text> ... </xsl:text>
      <xsl:value-of select="fn:string-join($mid//line[word=$t]/@no, ',')" />
      <xsl:text>&#xA;</xsl:text>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 6 - 10進数を2進数に基数変換する

LL Golf Hole 6 - 10進数を2進数に基数変換する (Nested Flatten)

短くなった。卑怯くさいけど。

#7254のコードを利用してますが、
基数だけは弄れるようにしておきました。

<stylesheet version="2.0" xmlns="http://www.w3.org/1999/XSL/Transform">
  <import href="http://tinyurl.com/58455r"/>
  <variable name="b" select="2"/>
</stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 6 - 10進数を2進数に基数変換する

LL Golf Hole 6 - 10進数を2進数に基数変換する (Nested Flatten)

正攻法で。
冒頭の 変数b の値が基数で、2～10まで対応してます。

短くとか.. 勘弁してください

<x:stylesheet version="2.0"
  xmlns:x="http://www.w3.org/1999/XSL/Transform"
  xmlns:s="http://www.w3.org/2001/XMLSchema"
  xmlns:f="http://www.w3.org/2005/xpath-functions"
  xmlns:y="uri:ja.doukaku.org:my-functions"
  >
  <x:variable name="b" as="s:integer" select="2"/>
  <x:output method="text"/>
  <x:template match="/">
    <x:for-each select="0 to 256">
      <x:value-of select="y:f(.)"/>
      <x:text>&#xA;</x:text>
    </x:for-each>
  </x:template>
  <x:function name="y:f" as="s:string">
    <x:param name="n" as="s:integer"/>
    <x:value-of select="if ($n=0) then '0' else f:string-join(f:reverse(y:g($n)),'')"/>
  </x:function>
  <x:function name="y:g" as="s:string*">
    <x:param name="n" as="s:integer"/>
    <x:if test="$n>0">
      <x:sequence select="s:string($n mod $b)"/>
      <x:sequence select="y:g($n idiv $b)"/>
    </x:if>
  </x:function>
</x:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 5 - 最上位の桁を数え上げる

LL Golf Hole 5 - 最上位の桁を数え上げる (Nested Flatten)

XPath の conditional expressions(if then else) など使ってみる。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  >

  <xsl:output method="text" />

  <xsl:variable name="goal" as="xs:string" select="'300'" />

  <xsl:template match="/" >
    <xsl:variable name="digit" as="xs:integer" select="fn:string-length($goal)" />
    <xsl:for-each select="1 to $digit">
      <xsl:variable name="d" as="xs:integer" select="." />
      <xsl:for-each select="(if (.=1) then 0 else 1)
                            to
                            (if (.=$digit) then xs:integer(fn:substring($goal,1,1)) else 9)" >
        <xsl:value-of select="." />
        <xsl:for-each select="2 to $d">
          <xsl:value-of select="0" />
        </xsl:for-each>
        <xsl:text>&#xA;</xsl:text>
      </xsl:for-each>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 1 - tinyurl.comを使ってURLを短縮する

LL Golf Hole 1 - tinyurl.comを使ってURLを短縮する (Nested Flatten)

#6827 の前に考えてたものを出し忘れていました。
しかしやはりXSLTはGolfに向かない。

1
2
3

<html x:version="2.0" xmlns:x="http://www.w3.org/1999/XSL/Transform">
<x:value-of select="unparsed-text('http://tinyurl.com/api-create.php?url=http://ll.jus.or.jp/2008/info/xgihyo')"/>
</html>

[ XSLT ] [ download code ] ]

turugina's comment on LL Golf Hole 2 - 文字列に含まれる単語の最初の文字を大文字にする

LL Golf Hole 2 - 文字列に含まれる単語の最初の文字を大文字にする (Nested Flatten)

XSLTもGolfには向きませんね。
本当は改行も全部消したかったんですが、
表示がエライことになるので止めました。
入力は↓のコード自身です。

<x:transform version="2.0"
xmlns:x="http://www.w3.org/1999/XSL/Transform"
xmlns:s="http://www.w3.org/2001/XMLSchema"
xmlns:f="http://www.w3.org/2005/xpath-functions">
<x:variable name="ll2008" as="s:string">LL future</x:variable>
<x:variable name="ll2005" as="s:string">LL day and night</x:variable>
<x:output method="text"/>
<x:template match="/">
<x:apply-templates select="/x:transform/x:variable"/>
</x:template>
<x:template match="x:variable">
<x:variable name="tokens" as="s:string*">
<x:for-each select="f:tokenize(./text(),' ')">
<x:sequence select="f:concat(f:upper-case(f:substring(.,1,1)),f:substring(.,2,f:string-length(.)-1))"/>
</x:for-each>
</x:variable>
<x:value-of select="f:concat(@name,'=')"/>
<x:value-of select="string-join($tokens,' ')"/>
<x:text>&#xA;</x:text>
</x:template>
</x:transform>

[ XSLT ] [ download code ] ]

turugina's comment on 設定ファイルから値を取得

設定ファイルから値を取得 (Nested Flatten)

こーゆーのが、XSLTの本来の使い方かと。

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  >

  <!-- 以下のようなxml文書を渡します
  <item name="りんご" cost="200" />
  -->

  <xsl:output method="text" encoding="sjis" />

  <xsl:template match="/item" >
    <xsl:call-template name="showPrice" />
  </xsl:template>

  <xsl:template name="showPrice">
    <xsl:text>「</xsl:text>
    <xsl:value-of select="@name" />
    <xsl:text>」は</xsl:text>
    <xsl:value-of select="floor(@cost * 1.05)" />
    <xsl:text>円（税込み）です。&#xA;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on /コメント/を取り除く

/*コメント*/を取り除く (Nested Flatten)

XSLT 2.0 ならregexが使えるので、

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:my="uri:ja.doukaku.org:my-functions"
  exclude-result-prefixes="my"
  >

  <xsl:output method="text" />

  <xsl:template match="/" >
    <xsl:value-of select="my:remove_comment('AAA')" />
    <xsl:text>&#xA;</xsl:text>
    <xsl:value-of select="my:remove_comment('AAA/*BBB*/')" />
    <xsl:text>&#xA;</xsl:text>
    <xsl:value-of select="my:remove_comment('AAA/*BBB')" />
    <xsl:text>&#xA;</xsl:text>
    <xsl:value-of select="my:remove_comment('AAA/*BBB*/CCC')" />
    <xsl:text>&#xA;</xsl:text>
    <xsl:value-of select="my:remove_comment('AAA/*BBB/*CCC*/DDD*/EEE')" />
    <xsl:text>&#xA;</xsl:text>
    <xsl:value-of select="my:remove_comment('AAA/a//*BB*B**/CCC')" />
    <xsl:text>&#xA;</xsl:text>
  </xsl:template>

  <xsl:function name="my:remove_comment" as="xs:string">
    <xsl:param name="str" as="xs:string" />

    <xsl:value-of
      select="fn:replace($str, '/\*.*?(\*/|$)', '')" />
  </xsl:function>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on アルファベットの繰り上がり

アルファベットの繰り上がり (Nested Flatten)

indexが1始まりだと混乱する...

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:my="uri:ja.doukaku.org:my-functions"
  exclude-result-prefixes="my"
  >

  <xsl:output method="text" />

  <xsl:variable name="convert_table" as="xs:string+">
    <xsl:for-each select="1 to 26">
      <xsl:sequence
        select="fn:codepoints-to-string(
        (fn:string-to-codepoints('A')[1] + . - 1)
        )" />
    </xsl:for-each>
  </xsl:variable>
  <xsl:variable name="table_size" as="xs:integer"
    select="fn:count($convert_table)" />

  <xsl:template match="/" >
    <xsl:variable name="seq" as="xs:string*">
      <xsl:for-each select="1 to 100">
        <xsl:sequence select="my:alphabeticalize(.)" />
      </xsl:for-each>
    </xsl:variable>

    <xsl:value-of select="fn:string-join($seq, ', ')" />
    <xsl:text>&#xA;</xsl:text>
  </xsl:template>

  <xsl:function name="my:alphabeticalize" as="xs:string">
    <xsl:param name="n" as="xs:integer" />

    <xsl:variable name="i" as="xs:integer" select="$n - 1" />

    <xsl:variable name="n_" as="xs:string"
      select="$convert_table[($i mod $table_size) + 1]" />

    <xsl:choose>
      <xsl:when test="$i idiv $table_size = 0">
        <xsl:value-of select="$n_" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of
          select="fn:concat(
          my:alphabeticalize($i idiv $table_size),
          $n_)" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:function>
</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on 与えられた数字のケタ数

与えられた数字のケタ数 (Nested Flatten)

負数にも対応させてみました。

出力結果：
2469 は 4 桁で、最大桁は 1000 の位です。
600 は 3 桁で、最大桁は 100 の位です。
1 は 1 桁で、最大桁は 1 の位です。
-65536 は 5 桁で、最大桁は -10000 の位です。

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  >

  <xsl:output method="text" encoding="sjis" />

  <xsl:template match="/" >
    <xsl:call-template name="digit">
      <xsl:with-param name="n" select="2469" />
    </xsl:call-template>
    <xsl:call-template name="digit">
      <xsl:with-param name="n" select="600" />
    </xsl:call-template>
    <xsl:call-template name="digit">
      <xsl:with-param name="n" select="1" />
    </xsl:call-template>
    <xsl:call-template name="digit">
      <xsl:with-param name="n" select="-65536" />
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="digit">
    <xsl:param name="n" as="xs:integer" />

    <xsl:variable name="is_negative" as="xs:boolean"
      select="$n&lt;0" />

    <xsl:variable name="n_" as="xs:string">
      <xsl:choose>
        <xsl:when test="$is_negative">
          <xsl:value-of select="xs:string(-1 * $n)" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="xs:string($n)" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>

    <xsl:value-of select="$n" />
    <xsl:text> は </xsl:text>
    <xsl:value-of select="string-length($n_)" />
    <xsl:text> 桁で、最大桁は </xsl:text>
    <xsl:if test="$is_negative">
      <xsl:text>-</xsl:text>
    </xsl:if>
    <xsl:text>1</xsl:text>
    <xsl:for-each select="1 to string-length($n_)-1">
      <xsl:text>0</xsl:text>
    </xsl:for-each>
    <xsl:text> の位です。&#xA;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on 年間カレンダー

年間カレンダー (Nested Flatten)

出力はシンプルなHTMLのtableで。
しかし、曜日を取得する関数を自作しなきゃいかんとわ...

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:my="uri:ja.doukaku.org:my-functions"
  exclude-result-prefixes="xs fn my"
  >

  <xsl:param name="n" as="xs:integer" >2008</xsl:param>

  <xsl:output method="html" />

  <xsl:template match="/" >
    <html>
      <head>
        <title><xsl:value-of select="$n" />年の年間カレンダー</title>
      </head>
      <body>
        <h1><xsl:value-of select="$n" />年の年間カレンダー</h1>
        <xsl:for-each select="1 to 12">
          <hr />
          <h2><xsl:value-of select="." />月</h2>
          <xsl:call-template name="mcalender">
            <xsl:with-param name="year" select="$n" />
            <xsl:with-param name="month" select="." />
          </xsl:call-template>
        </xsl:for-each>
      </body>
    </html>
  </xsl:template>

  <xsl:template name="mcalender">
    <xsl:param name="year" as="xs:integer" />
    <xsl:param name="month" as="xs:integer" />

    <!-- 今月1日 -->
    <xsl:variable name="first-date" as="xs:date"
      select="xs:date(
        fn:string-join(
          (my:pad($year,4),my:pad($month,2),'01'),
          '-'))" />
    <!-- 次月1日 -->
    <xsl:variable name="next-first-date" as="xs:date">
      <xsl:choose>
        <xsl:when test="$month=12">
          <xsl:value-of
            select="xs:date(
              fn:string-join(
                (my:pad($year+1,4),'01','01'),
                '-'))" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of
            select="xs:date(
              fn:string-join(
                (my:pad($year,4),my:pad($month+1,2),'01'),
                '-'))" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <!-- 今月の日数を求める -->
    <xsl:variable name="days" as="xs:integer"
      select="fn:days-from-duration($next-first-date - $first-date)" />

    <!-- 今月1日 の曜日を求める -->
    <xsl:variable name="start-day" as="xs:integer"
      select="my:get-day($first-date)" />

    <!-- カレンダーの左上の開始日 -->
    <xsl:variable name="rstart" as="xs:integer"
      select="1 - $start-day" />
    <!-- カレンダーの右下の終了日 -->
    <xsl:variable name="rend" as="xs:integer">
      <xsl:choose>
        <xsl:when test="(($days - $rstart + 1) mod 7)=0">
          <xsl:value-of select="$days - $rstart + 1" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="((($days - $rstart+1) idiv 7)+1)*7" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>

    <table border="1">
      <xsl:call-template name="calender-header" />
      <xsl:for-each select="1 to $rend idiv 7">
        <tr>
          <xsl:for-each select="$rstart+((.-1)*7) to $rstart+(.*7)-1">
            <td>
              <xsl:choose>
                <xsl:when test="1 &lt;= . and . &lt;= $days">
                  <xsl:value-of select="." />
                </xsl:when>
                <xsl:otherwise>
                  <xsl:text>&#160;</xsl:text>
                </xsl:otherwise>
              </xsl:choose>
            </td>
          </xsl:for-each>
        </tr>
      </xsl:for-each>
    </table>
  </xsl:template>

  <xsl:template name="calender-header">
    <tr>
      <xsl:for-each select="('日','月','火','水','木','金','土')">
        <th><xsl:value-of select="." /></th>
      </xsl:for-each>
    </tr>
  </xsl:template>

  <!-- 曜日を取得する -->
  <xsl:function name="my:get-day" as="xs:integer">
    <xsl:param name="date" as="xs:date" />
    <xsl:variable name="epoch" as="xs:date"
      select="xs:date('1970-01-01')" />

    <xsl:variable name="day" as="xs:integer"
      select="(fn:days-from-duration($date - $epoch) + 4) mod 7" />
    <xsl:choose>
      <xsl:when test="$day &lt; 0">
        <xsl:value-of select="$day + 7" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$day" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:function>

  <xsl:function name="my:pad" as="xs:string">
    <xsl:param name="i" as="xs:integer" />
    <xsl:param name="digit" as="xs:integer" />

    <xsl:variable name="seq" as="xs:string*">
      <xsl:for-each
        select="1 to $digit - fn:string-length(xs:string($i))">
        <xsl:sequence select="'0'" />
      </xsl:for-each>
      <xsl:sequence select="xs:string($i)" />
    </xsl:variable>

    <xsl:value-of select="fn:string-join($seq, '')" />
  </xsl:function>
</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on 与えられた文字列でピラミッド

与えられた文字列でピラミッド (Nested Flatten)

対象文字列はテンプレートパラメタ txt で渡してください。

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  >

  <xsl:param name="txt" as="xs:string" />

  <xsl:output method="text" />

  <xsl:template match="/" >
    <xsl:variable name="chars" as="xs:string*">
      <xsl:for-each select="fn:string-to-codepoints($txt)">
        <xsl:sequence select="fn:codepoints-to-string((.))" />
      </xsl:for-each>
    </xsl:variable>

    <xsl:for-each select="1 to fn:count($chars)">
      <xsl:variable name="wscount" as="xs:integer"
        select="fn:count($chars)-." />
      <xsl:for-each select="1 to $wscount" >
        <xsl:text> </xsl:text>
      </xsl:for-each>
      <xsl:value-of select="fn:subsequence($chars, $wscount+1)" />
      <xsl:text>&#xA;</xsl:text>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on ダブル完全数

ダブル完全数 (Nested Flatten)

べたに計算してます。

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:my="uri:ja.doukaku.org:my-functions"
  exclude-result-prefixes="my"
  >

  <xsl:output method="text" encoding="sjis" />

  <xsl:template match="/" >
    <xsl:for-each select="1 to 10000">
      <xsl:if test="fn:sum(my:get-divisors(.))=.*2">
        <xsl:value-of select="." />
        <xsl:text> はダブル完全数&#xA;</xsl:text>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

  <xsl:function name="my:get-divisors" as="xs:integer*">
    <xsl:param name="n" as="xs:integer" />

    <xsl:if test="$n&gt;1">
      <xsl:for-each select="1 to $n idiv 2">
        <xsl:if test="($n mod .)=0">
          <xsl:sequence select="." />
        </xsl:if>
      </xsl:for-each>
    </xsl:if>
  </xsl:function>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

turugina's comment on HTTPでGET

HTTPでGET (Nested Flatten)

unparsed-text() を使って。
よっぽどひねくれた実装でもない限り
GETでとってくると思います。

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  >

  <xsl:output method="text" />

  <xsl:template match="/" >
    <xsl:value-of select="unparsed-text('http://ja.doukaku.org/feeds/comments/')" />
  </xsl:template>

</xsl:stylesheet>

[ XSLT ] [ download code ] ]

Latest comments for language 'XSLT' on doukaku.org

turugina's comment on 文字列型日時ののN秒後時間取得

turugina's comment on 文字列型日時ののN秒後時間取得

turugina's comment on LL Golf Hole 8 - 横向きのピラミッドを作る

turugina's comment on LL Golf Hole 7 - バイト数を読みやすくする

turugina's comment on 除算・余剰を使わずに閏年

turugina's comment on LL Golf Hole 3 - 13日の金曜日を数え上げる

turugina's comment on LL Golf Hole 4 - 文章から単語の索引を作る

turugina's comment on LL Golf Hole 6 - 10進数を2進数に基数変換する

turugina's comment on LL Golf Hole 6 - 10進数を2進数に基数変換する

turugina's comment on LL Golf Hole 5 - 最上位の桁を数え上げる

turugina's comment on LL Golf Hole 1 - tinyurl.comを使ってURLを短縮する

turugina's comment on LL Golf Hole 2 - 文字列に含まれる単語の最初の文字を大文字にする

turugina's comment on 設定ファイルから値を取得

turugina's comment on /*コメント*/を取り除く

turugina's comment on アルファベットの繰り上がり

turugina's comment on 与えられた数字のケタ数

turugina's comment on 年間カレンダー

turugina's comment on 与えられた文字列でピラミッド

turugina's comment on ダブル完全数

turugina's comment on HTTPでGET

turugina's comment on /コメント/を取り除く